kim_energy_unit_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api.git repository.
!

module kim_energy_unit_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_energy_unit_type, &
    ! Constants
    kim_energy_unit_unused, &
    kim_energy_unit_amu_a2_per_ps2, &
    kim_energy_unit_erg, &
    kim_energy_unit_ev, &
    kim_energy_unit_hartree, &
    kim_energy_unit_j, &
    kim_energy_unit_kcal_mol, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_energy_units, &
    kim_get_energy_unit

  type, bind(c) :: kim_energy_unit_type
    integer(c_int) energy_unit_id
  end type kim_energy_unit_type

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_unused") &
    :: kim_energy_unit_unused

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_amu_A2_per_ps2") &
    :: kim_energy_unit_amu_a2_per_ps2

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_erg") &
    :: kim_energy_unit_erg

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_eV") &
    :: kim_energy_unit_ev

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_Hartree") &
    :: kim_energy_unit_hartree

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_J") &
    :: kim_energy_unit_j

  type(kim_energy_unit_type), protected, save, &
    bind(c, name="KIM_ENERGY_UNIT_kcal_mol") &
    :: kim_energy_unit_kcal_mol

  interface kim_known
    module procedure kim_energy_unit_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_energy_unit_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_energy_unit_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_energy_unit_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_energy_unit_to_string
  end interface kim_to_string

contains
  logical recursive function kim_energy_unit_known(energy_unit)
    implicit none
    interface
      integer(c_int) recursive function known(energy_unit) &
        bind(c, name="KIM_EnergyUnit_Known")
        use, intrinsic :: iso_c_binding
        import kim_energy_unit_type
        implicit none
        type(kim_energy_unit_type), intent(in), value :: energy_unit
      end function known
    end interface
    type(kim_energy_unit_type), intent(in) :: energy_unit

    kim_energy_unit_known = (known(energy_unit) /= 0)
  end function kim_energy_unit_known

  logical recursive function kim_energy_unit_equal(lhs, rhs)
    implicit none
    type(kim_energy_unit_type), intent(in) :: lhs
    type(kim_energy_unit_type), intent(in) :: rhs

    kim_energy_unit_equal &
      = (lhs%energy_unit_id == rhs%energy_unit_id)
  end function kim_energy_unit_equal

  logical recursive function kim_energy_unit_not_equal(lhs, rhs)
    implicit none
    type(kim_energy_unit_type), intent(in) :: lhs
    type(kim_energy_unit_type), intent(in) :: rhs

    kim_energy_unit_not_equal = .not. (lhs == rhs)
  end function kim_energy_unit_not_equal

  recursive subroutine kim_energy_unit_from_string(string, energy_unit)
    implicit none
    interface
      type(kim_energy_unit_type) recursive function from_string(string) &
        bind(c, name="KIM_EnergyUnit_FromString")
        use, intrinsic :: iso_c_binding
        import kim_energy_unit_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_energy_unit_type), intent(out) :: energy_unit

    energy_unit = from_string(trim(string)//c_null_char)
  end subroutine kim_energy_unit_from_string

  recursive subroutine kim_energy_unit_to_string(energy_unit, string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(energy_unit) &
        bind(c, name="KIM_EnergyUnit_ToString")
        use, intrinsic :: iso_c_binding
        import kim_energy_unit_type
        implicit none
        type(kim_energy_unit_type), intent(in), value :: energy_unit
      end function get_string
    end interface
    type(kim_energy_unit_type), intent(in) :: energy_unit
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(energy_unit)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_energy_unit_to_string

  recursive subroutine kim_get_number_of_energy_units(number_of_energy_units)
    implicit none
    interface
      recursive subroutine get_number_of_energy_units(number_of_energy_units) &
        bind(c, name="KIM_ENERGY_UNIT_GetNumberOfEnergyUnits")
        use, intrinsic :: iso_c_binding
        integer(c_int), intent(out) :: number_of_energy_units
      end subroutine get_number_of_energy_units
    end interface
    integer(c_int), intent(out) :: number_of_energy_units

    call get_number_of_energy_units(number_of_energy_units)
  end subroutine kim_get_number_of_energy_units

  recursive subroutine kim_get_energy_unit(index, energy_unit, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_energy_unit(index, energy_unit) &
        bind(c, name="KIM_ENERGY_UNIT_GetEnergyUnit")
        use, intrinsic :: iso_c_binding
        import kim_energy_unit_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_energy_unit_type), intent(out) :: energy_unit
      end function get_energy_unit
    end interface
    integer(c_int), intent(in) :: index
    type(kim_energy_unit_type), intent(out) :: energy_unit
    integer(c_int), intent(out) :: ierr

    ierr = get_energy_unit(index - 1, energy_unit)
  end subroutine kim_get_energy_unit
end module kim_energy_unit_module