kim_support_status_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api.git repository.
!

module kim_support_status_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_support_status_type, &
    ! Constants
    kim_support_status_required_by_api, &
    kim_support_status_not_supported, &
    kim_support_status_required, &
    kim_support_status_optional, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_support_statuses, &
    kim_get_support_status

  type, bind(c) :: kim_support_status_type
    integer(c_int) :: support_status_id
  end type kim_support_status_type

  type(kim_support_status_type), protected, save, &
    bind(c, name="KIM_SUPPORT_STATUS_requiredByAPI") &
    :: kim_support_status_required_by_api

  type(kim_support_status_type), protected, save, &
    bind(c, name="KIM_SUPPORT_STATUS_notSupported") &
    :: kim_support_status_not_supported

  type(kim_support_status_type), protected, save, &
    bind(c, name="KIM_SUPPORT_STATUS_required") &
    :: kim_support_status_required

  type(kim_support_status_type), protected, save, &
    bind(c, name="KIM_SUPPORT_STATUS_optional") &
    :: kim_support_status_optional

  interface kim_known
    module procedure kim_support_status_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_support_status_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_support_status_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_support_status_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_support_status_to_string
  end interface kim_to_string

contains
  logical recursive function kim_support_status_known(support_status)
    implicit none
    interface
      integer(c_int) recursive function known(support_status) &
        bind(c, name="KIM_SupportStatus_Known")
        use, intrinsic :: iso_c_binding
        import kim_support_status_type
        implicit none
        type(kim_support_status_type), intent(in), value :: support_status
      end function known
    end interface
    type(kim_support_status_type), intent(in) :: support_status

    kim_support_status_known = (known(support_status) /= 0)
  end function kim_support_status_known

  logical recursive function kim_support_status_equal(lhs, rhs)
    implicit none
    type(kim_support_status_type), intent(in) :: lhs
    type(kim_support_status_type), intent(in) :: rhs

    kim_support_status_equal &
      = (lhs%support_status_id == rhs%support_status_id)
  end function kim_support_status_equal

  logical recursive function kim_support_status_not_equal(lhs, rhs)
    implicit none
    type(kim_support_status_type), intent(in) :: lhs
    type(kim_support_status_type), intent(in) :: rhs

    kim_support_status_not_equal = .not. (lhs == rhs)
  end function kim_support_status_not_equal

  recursive subroutine kim_support_status_from_string(string, support_status)
    implicit none
    interface
      type(kim_support_status_type) recursive function from_string(string) &
        bind(c, name="KIM_SupportStatus_FromString")
        use, intrinsic :: iso_c_binding
        import kim_support_status_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_support_status_type), intent(out) :: support_status

    support_status = from_string(trim(string)//c_null_char)
  end subroutine kim_support_status_from_string

  recursive subroutine kim_support_status_to_string(support_status, string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(support_status) &
        bind(c, name="KIM_SupportStatus_ToString")
        use, intrinsic :: iso_c_binding
        import kim_support_status_type
        implicit none
        type(kim_support_status_type), intent(in), value :: support_status
      end function get_string
    end interface
    type(kim_support_status_type), intent(in) :: support_status
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(support_status)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_support_status_to_string

  recursive subroutine kim_get_number_of_support_statuses( &
    number_of_support_statuses)
    implicit none
    interface
      recursive subroutine get_number_of_support_statuses( &
        number_of_support_statuses) &
        bind(c, name="KIM_SUPPORT_STATUS_GetNumberOfSupportStatuses")
        use, intrinsic :: iso_c_binding
        implicit none
        integer(c_int), intent(out) :: number_of_support_statuses
      end subroutine get_number_of_support_statuses
    end interface
    integer(c_int), intent(out) :: number_of_support_statuses

    call get_number_of_support_statuses(number_of_support_statuses)
  end subroutine kim_get_number_of_support_statuses

  recursive subroutine kim_get_support_status(index, support_status, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_support_status(index, &
                                                           support_status) &
        bind(c, name="KIM_SUPPORT_STATUS_GetSupportStatus")
        use, intrinsic :: iso_c_binding
        import kim_support_status_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_support_status_type), intent(out) :: support_status
      end function get_support_status
    end interface
    integer(c_int), intent(in) :: index
    type(kim_support_status_type), intent(out) :: support_status
    integer(c_int), intent(out) :: ierr

    ierr = get_support_status(index - 1, support_status)
  end subroutine kim_get_support_status
end module kim_support_status_module