kim_collection_item_type_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api-2.3.0 package.
!

module kim_collection_item_type_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_collection_item_type_type, &
    ! Constants
    kim_collection_item_type_model_driver, &
    kim_collection_item_type_portable_model, &
    kim_collection_item_type_simulator_model, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_collection_item_types, &
    kim_get_collection_item_type

  type, bind(c) :: kim_collection_item_type_type
    integer(c_int) collection_item_type_id
  end type kim_collection_item_type_type

  type(kim_collection_item_type_type), protected, save, &
    bind(c, name="KIM_COLLECTION_ITEM_TYPE_modelDriver") &
    :: kim_collection_item_type_model_driver

  type(kim_collection_item_type_type), protected, save, &
    bind(c, name="KIM_COLLECTION_ITEM_TYPE_portableModel") &
    :: kim_collection_item_type_portable_model

  type(kim_collection_item_type_type), protected, save, &
    bind(c, name="KIM_COLLECTION_ITEM_TYPE_simulatorModel") &
    :: kim_collection_item_type_simulator_model

  interface kim_known
    module procedure kim_collection_item_type_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_collection_item_type_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_collection_item_type_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_collection_item_type_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_collection_item_type_to_string
  end interface kim_to_string

contains
  logical recursive function kim_collection_item_type_known( &
    collection_item_type)
    implicit none
    interface
      integer(c_int) recursive function known(collection_item_type) &
        bind(c, name="KIM_CollectionItemType_Known")
        use, intrinsic :: iso_c_binding
        import kim_collection_item_type_type
        implicit none
        type(kim_collection_item_type_type), intent(in), value :: &
          collection_item_type
      end function known
    end interface
    type(kim_collection_item_type_type), intent(in) :: collection_item_type

    kim_collection_item_type_known = (known(collection_item_type) /= 0)
  end function kim_collection_item_type_known

  logical recursive function kim_collection_item_type_equal(lhs, rhs)
    implicit none
    type(kim_collection_item_type_type), intent(in) :: lhs
    type(kim_collection_item_type_type), intent(in) :: rhs

    kim_collection_item_type_equal &
      = (lhs%collection_item_type_id == rhs%collection_item_type_id)
  end function kim_collection_item_type_equal

  logical recursive function kim_collection_item_type_not_equal(lhs, rhs)
    implicit none
    type(kim_collection_item_type_type), intent(in) :: lhs
    type(kim_collection_item_type_type), intent(in) :: rhs

    kim_collection_item_type_not_equal = .not. (lhs == rhs)
  end function kim_collection_item_type_not_equal

  recursive subroutine kim_collection_item_type_from_string( &
    string, collection_item_type)
    implicit none
    interface
      type(kim_collection_item_type_type) recursive function &
        from_string(string) bind(c, name="KIM_CollectionItemType_FromString")
        use, intrinsic :: iso_c_binding
        import kim_collection_item_type_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_collection_item_type_type), intent(out) :: collection_item_type

    collection_item_type = from_string(trim(string)//c_null_char)
  end subroutine kim_collection_item_type_from_string

  recursive subroutine kim_collection_item_type_to_string( &
    collection_item_type, string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(collection_item_type) &
        bind(c, name="KIM_CollectionItemType_ToString")
        use, intrinsic :: iso_c_binding
        import kim_collection_item_type_type
        implicit none
        type(kim_collection_item_type_type), intent(in), value :: &
          collection_item_type
      end function get_string
    end interface
    type(kim_collection_item_type_type), intent(in) :: collection_item_type
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(collection_item_type)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_collection_item_type_to_string

  recursive subroutine kim_get_number_of_collection_item_types( &
    number_of_collection_item_types)
    implicit none
    interface
      recursive subroutine get_number_of_collection_item_types( &
        number_of_collection_item_types) &
        bind(c, name="KIM_COLLECTION_ITEM_TYPE_GetNumberOfCollectionItemTypes")
        use, intrinsic :: iso_c_binding
        implicit none
        integer(c_int), intent(out) :: number_of_collection_item_types
      end subroutine get_number_of_collection_item_types
    end interface
    integer(c_int), intent(out) :: number_of_collection_item_types

    call get_number_of_collection_item_types(number_of_collection_item_types)
  end subroutine kim_get_number_of_collection_item_types

  recursive subroutine kim_get_collection_item_type(index, &
                                                    collection_item_type, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_collection_item_type( &
        index, collection_item_type) &
        bind(c, name="KIM_COLLECTION_ITEM_TYPE_GetCollectionItemType")
        use, intrinsic :: iso_c_binding
        import kim_collection_item_type_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_collection_item_type_type), intent(out) :: collection_item_type
      end function get_collection_item_type
    end interface
    integer(c_int), intent(in) :: index
    type(kim_collection_item_type_type), intent(out) :: collection_item_type
    integer(c_int), intent(out) :: ierr

    ierr = get_collection_item_type(index - 1, collection_item_type)
  end subroutine kim_get_collection_item_type
end module kim_collection_item_type_module