kim_collection_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api-2.3.0 package.
!

module kim_collection_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_collection_type, &
    ! Constants
    kim_collection_system, &
    kim_collection_user, &
    kim_collection_environment_variable, &
    kim_collection_current_working_directory, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_collections, &
    kim_get_collection

  type, bind(c) :: kim_collection_type
    integer(c_int) collection_id
  end type kim_collection_type

  type(kim_collection_type), protected, save, &
    bind(c, name="KIM_COLLECTION_system") &
    :: kim_collection_system

  type(kim_collection_type), protected, save, &
    bind(c, name="KIM_COLLECTION_user") &
    :: kim_collection_user

  type(kim_collection_type), protected, save, &
    bind(c, name="KIM_COLLECTION_environmentVariable") &
    :: kim_collection_environment_variable

  type(kim_collection_type), protected, save, &
    bind(c, name="KIM_COLLECTION_currentWorkingDirectory") &
    :: kim_collection_current_working_directory

  interface kim_known
    module procedure kim_collection_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_collection_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_collection_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_collection_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_collection_to_string
  end interface kim_to_string

contains
  logical recursive function kim_collection_known(collection)
    implicit none
    interface
      integer(c_int) recursive function known(collection) &
        bind(c, name="KIM_Collection_Known")
        use, intrinsic :: iso_c_binding
        import kim_collection_type
        implicit none
        type(kim_collection_type), intent(in), value :: collection
      end function known
    end interface
    type(kim_collection_type), intent(in) :: collection

    kim_collection_known = (known(collection) /= 0)
  end function kim_collection_known

  logical recursive function kim_collection_equal(lhs, rhs)
    implicit none
    type(kim_collection_type), intent(in) :: lhs
    type(kim_collection_type), intent(in) :: rhs

    kim_collection_equal &
      = (lhs%collection_id == rhs%collection_id)
  end function kim_collection_equal

  logical recursive function kim_collection_not_equal(lhs, rhs)
    implicit none
    type(kim_collection_type), intent(in) :: lhs
    type(kim_collection_type), intent(in) :: rhs

    kim_collection_not_equal = .not. (lhs == rhs)
  end function kim_collection_not_equal

  recursive subroutine kim_collection_from_string(string, collection)
    implicit none
    interface
      type(kim_collection_type) recursive function from_string(string) &
        bind(c, name="KIM_Collection_FromString")
        use, intrinsic :: iso_c_binding
        import kim_collection_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_collection_type), intent(out) :: collection

    collection = from_string(trim(string)//c_null_char)
  end subroutine kim_collection_from_string

  recursive subroutine kim_collection_to_string(collection, string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(collection) &
        bind(c, name="KIM_Collection_ToString")
        use, intrinsic :: iso_c_binding
        import kim_collection_type
        implicit none
        type(kim_collection_type), intent(in), value :: collection
      end function get_string
    end interface
    type(kim_collection_type), intent(in) :: collection
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(collection)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_collection_to_string

  recursive subroutine kim_get_number_of_collections(number_of_collections)
    implicit none
    interface
      recursive subroutine get_number_of_collections(number_of_collections) &
        bind(c, name="KIM_COLLECTION_GetNumberOfCollections")
        use, intrinsic :: iso_c_binding
        implicit none
        integer(c_int), intent(out) :: number_of_collections
      end subroutine get_number_of_collections
    end interface
    integer(c_int), intent(out) :: number_of_collections

    call get_number_of_collections(number_of_collections)
  end subroutine kim_get_number_of_collections

  recursive subroutine kim_get_collection(index, collection, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_collection(index, collection) &
        bind(c, name="KIM_COLLECTION_GetCollection")
        use, intrinsic :: iso_c_binding
        import kim_collection_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_collection_type), intent(out) :: collection
      end function get_collection
    end interface
    integer(c_int), intent(in) :: index
    type(kim_collection_type), intent(out) :: collection
    integer(c_int), intent(out) :: ierr

    ierr = get_collection(index - 1, collection)
  end subroutine kim_get_collection
end module kim_collection_module