kim_compute_argument_name_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api-2.3.0 package.
!

module kim_compute_argument_name_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_compute_argument_name_type, &
    ! Constants
    kim_compute_argument_name_number_of_particles, &
    kim_compute_argument_name_particle_species_codes, &
    kim_compute_argument_name_particle_contributing, &
    kim_compute_argument_name_coordinates, &
    kim_compute_argument_name_partial_energy, &
    kim_compute_argument_name_partial_forces, &
    kim_compute_argument_name_partial_particle_energy, &
    kim_compute_argument_name_partial_virial, &
    kim_compute_argument_name_partial_particle_virial, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_compute_argument_names, &
    kim_get_compute_argument_name, &
    kim_get_compute_argument_data_type

  type, bind(c) :: kim_compute_argument_name_type
    integer(c_int) compute_argument_name_id
  end type kim_compute_argument_name_type

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_numberOfParticles") &
    :: kim_compute_argument_name_number_of_particles

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_particleSpeciesCodes") &
    :: kim_compute_argument_name_particle_species_codes

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_particleContributing") &
    :: kim_compute_argument_name_particle_contributing

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_coordinates") &
    :: kim_compute_argument_name_coordinates

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_partialEnergy") &
    :: kim_compute_argument_name_partial_energy

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_partialForces") &
    :: kim_compute_argument_name_partial_forces

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_partialParticleEnergy") &
    :: kim_compute_argument_name_partial_particle_energy

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_partialVirial") &
    :: kim_compute_argument_name_partial_virial

  type(kim_compute_argument_name_type), protected, save, &
    bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_partialParticleVirial") &
    :: kim_compute_argument_name_partial_particle_virial

  interface kim_known
    module procedure kim_compute_argument_name_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_compute_argument_name_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_compute_argument_name_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_compute_argument_name_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_compute_argument_name_to_string
  end interface kim_to_string

contains
  logical recursive function kim_compute_argument_name_known( &
    compute_argument_name)
    implicit none
    interface
      integer(c_int) recursive function known(compute_argument_name) &
        bind(c, name="KIM_ComputeArgumentName_Known")
        use, intrinsic :: iso_c_binding
        import kim_compute_argument_name_type
        implicit none
        type(kim_compute_argument_name_type), intent(in), value :: &
          compute_argument_name
      end function known
    end interface
    type(kim_compute_argument_name_type), intent(in) :: compute_argument_name

    kim_compute_argument_name_known = (known(compute_argument_name) /= 0)
  end function kim_compute_argument_name_known

  logical recursive function kim_compute_argument_name_equal(lhs, rhs)
    implicit none
    type(kim_compute_argument_name_type), intent(in) :: lhs
    type(kim_compute_argument_name_type), intent(in) :: rhs

    kim_compute_argument_name_equal &
      = (lhs%compute_argument_name_id == rhs%compute_argument_name_id)
  end function kim_compute_argument_name_equal

  logical recursive function kim_compute_argument_name_not_equal(lhs, rhs)
    implicit none
    type(kim_compute_argument_name_type), intent(in) :: lhs
    type(kim_compute_argument_name_type), intent(in) :: rhs

    kim_compute_argument_name_not_equal = .not. (lhs == rhs)
  end function kim_compute_argument_name_not_equal

  recursive subroutine kim_compute_argument_name_from_string( &
    string, compute_argument_name)
    implicit none
    interface
      type(kim_compute_argument_name_type) recursive function from_string( &
        string) bind(c, name="KIM_ComputeArgumentName_FromString")
        use, intrinsic :: iso_c_binding
        import kim_compute_argument_name_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_compute_argument_name_type), intent(out) :: compute_argument_name

    compute_argument_name = from_string(trim(string)//c_null_char)
  end subroutine kim_compute_argument_name_from_string

  recursive subroutine kim_compute_argument_name_to_string( &
    compute_argument_name, string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(compute_argument_name) &
        bind(c, name="KIM_ComputeArgumentName_ToString")
        use, intrinsic :: iso_c_binding
        import kim_compute_argument_name_type
        implicit none
        type(kim_compute_argument_name_type), intent(in), value :: &
          compute_argument_name
      end function get_string
    end interface
    type(kim_compute_argument_name_type), intent(in) :: &
      compute_argument_name
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(compute_argument_name)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_compute_argument_name_to_string

  recursive subroutine kim_get_number_of_compute_argument_names( &
    number_of_compute_argument_names)
    implicit none
    interface
      recursive subroutine get_number_of_compute_argument_names( &
        number_of_compute_argument_names) &
        bind(c, &
             name="KIM_COMPUTE_ARGUMENT_NAME_GetNumberOfComputeArgumentNames")
        use, intrinsic :: iso_c_binding
        integer(c_int), intent(out) :: number_of_compute_argument_names
      end subroutine get_number_of_compute_argument_names
    end interface
    integer(c_int), intent(out) :: number_of_compute_argument_names

    call get_number_of_compute_argument_names(number_of_compute_argument_names)
  end subroutine kim_get_number_of_compute_argument_names

  recursive subroutine kim_get_compute_argument_name( &
    index, compute_argument_name, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_compute_argument_name( &
        index, compute_argument_name) &
        bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_GetComputeArgumentName")
        use, intrinsic :: iso_c_binding
        import kim_compute_argument_name_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_compute_argument_name_type), intent(out) :: &
          compute_argument_name
      end function get_compute_argument_name
    end interface
    integer(c_int), intent(in) :: index
    type(kim_compute_argument_name_type), intent(out) :: compute_argument_name
    integer(c_int), intent(out) :: ierr

    ierr = get_compute_argument_name(index - 1, compute_argument_name)
  end subroutine kim_get_compute_argument_name

  recursive subroutine kim_get_compute_argument_data_type( &
    compute_argument_name, &
    data_type, ierr)
    use kim_data_type_module, only: kim_data_type_type
    implicit none
    interface
      integer(c_int) recursive function get_compute_argument_data_type( &
        compute_argument_name, data_type) &
        bind(c, name="KIM_COMPUTE_ARGUMENT_NAME_GetComputeArgumentDataType")
        use, intrinsic :: iso_c_binding
        use kim_data_type_module, only: kim_data_type_type
        import kim_compute_argument_name_type
        implicit none
        type(kim_compute_argument_name_type), intent(in), value :: &
          compute_argument_name
        type(kim_data_type_type), intent(out) :: data_type
      end function get_compute_argument_data_type
    end interface
    type(kim_compute_argument_name_type), intent(in) :: &
      compute_argument_name
    type(kim_data_type_type), intent(out) :: data_type
    integer(c_int), intent(out) :: ierr

    ierr = get_compute_argument_data_type(compute_argument_name, data_type)
  end subroutine kim_get_compute_argument_data_type
end module kim_compute_argument_name_module