kim_model_routine_name_module.f90

Go to the documentation of this file.

!
! KIM-API: An API for interatomic models
! Copyright (c) 2013--2022, Regents of the University of Minnesota.
! All rights reserved.
!
! Contributors:
!    Ryan S. Elliott
!
! SPDX-License-Identifier: LGPL-2.1-or-later
!
! This library is free software; you can redistribute it and/or
! modify it under the terms of the GNU Lesser General Public
! License as published by the Free Software Foundation; either
! version 2.1 of the License, or (at your option) any later version.
!
! This library is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
! Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public License
! along with this library; if not, write to the Free Software Foundation,
! Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
!

!
! Release: This file is part of the kim-api-2.3.0 package.
!

module kim_model_routine_name_module
  use, intrinsic :: iso_c_binding
  implicit none
  private

  public &
    ! Derived types
    kim_model_routine_name_type, &
    ! Constants
    kim_model_routine_name_create, &
    kim_model_routine_name_compute_arguments_create, &
    kim_model_routine_name_compute, &
    kim_model_routine_name_extension, &
    kim_model_routine_name_refresh, &
    kim_model_routine_name_write_parameterized_model, &
    kim_model_routine_name_compute_arguments_destroy, &
    kim_model_routine_name_destroy, &
    ! Routines
    kim_known, &
    operator(.eq.), &
    operator(.ne.), &
    kim_from_string, &
    kim_to_string, &
    kim_get_number_of_model_routine_names, &
    kim_get_model_routine_name

  type, bind(c) :: kim_model_routine_name_type
    integer(c_int) model_routine_name_id
  end type kim_model_routine_name_type

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_Create") &
    :: kim_model_routine_name_create

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_ComputeArgumentsCreate") &
    :: kim_model_routine_name_compute_arguments_create

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_Compute") &
    :: kim_model_routine_name_compute

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_Extension") &
    :: kim_model_routine_name_extension

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_Refresh") &
    :: kim_model_routine_name_refresh

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_WriteParameterizedModel") &
    :: kim_model_routine_name_write_parameterized_model

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_ComputeArgumentsDestroy") &
    :: kim_model_routine_name_compute_arguments_destroy

  type(kim_model_routine_name_type), protected, save, &
    bind(c, name="KIM_MODEL_ROUTINE_NAME_Destroy") &
    :: kim_model_routine_name_destroy

  interface kim_known
    module procedure kim_model_routine_name_known
  end interface kim_known

  interface operator(.eq.)
    module procedure kim_model_routine_name_equal
  end interface operator(.eq.)

  interface operator(.ne.)
    module procedure kim_model_routine_name_not_equal
  end interface operator(.ne.)

  interface kim_from_string
    module procedure kim_model_routine_name_from_string
  end interface kim_from_string

  interface kim_to_string
    module procedure kim_model_routine_name_to_string
  end interface kim_to_string

contains
  logical recursive function kim_model_routine_name_known(model_routine_name)
    implicit none
    interface
      integer(c_int) recursive function known(model_routine_name) &
        bind(c, name="KIM_ModelRoutineName_Known")
        use, intrinsic :: iso_c_binding
        import kim_model_routine_name_type
        implicit none
        type(kim_model_routine_name_type), intent(in), value :: &
          model_routine_name
      end function known
    end interface
    type(kim_model_routine_name_type), intent(in) :: model_routine_name

    kim_model_routine_name_known = (known(model_routine_name) /= 0)
  end function kim_model_routine_name_known

  logical recursive function kim_model_routine_name_equal(lhs, rhs)
    implicit none
    type(kim_model_routine_name_type), intent(in) :: lhs
    type(kim_model_routine_name_type), intent(in) :: rhs

    kim_model_routine_name_equal &
      = (lhs%model_routine_name_id == rhs%model_routine_name_id)
  end function kim_model_routine_name_equal

  logical recursive function kim_model_routine_name_not_equal(lhs, rhs)
    implicit none
    type(kim_model_routine_name_type), intent(in) :: lhs
    type(kim_model_routine_name_type), intent(in) :: rhs

    kim_model_routine_name_not_equal = .not. (lhs == rhs)
  end function kim_model_routine_name_not_equal

  recursive subroutine kim_model_routine_name_from_string(string, &
                                                          model_routine_name)
    implicit none
    interface
      type(kim_model_routine_name_type) recursive function from_string(string) &
        bind(c, name="KIM_ModelRoutineName_FromString")
        use, intrinsic :: iso_c_binding
        import kim_model_routine_name_type
        implicit none
        character(c_char), intent(in) :: string(*)
      end function from_string
    end interface
    character(len=*, kind=c_char), intent(in) :: string
    type(kim_model_routine_name_type), intent(out) :: model_routine_name

    model_routine_name = from_string(trim(string)//c_null_char)
  end subroutine kim_model_routine_name_from_string

  recursive subroutine kim_model_routine_name_to_string(model_routine_name, &
                                                        string)
    use kim_convert_string_module, only: kim_convert_c_char_ptr_to_string
    implicit none
    interface
      type(c_ptr) recursive function get_string(model_routine_name) &
        bind(c, name="KIM_ModelRoutineName_ToString")
        use, intrinsic :: iso_c_binding
        import kim_model_routine_name_type
        implicit none
        type(kim_model_routine_name_type), intent(in), value :: &
          model_routine_name
      end function get_string
    end interface
    type(kim_model_routine_name_type), intent(in) :: &
      model_routine_name
    character(len=*, kind=c_char), intent(out) :: string

    type(c_ptr) :: p

    p = get_string(model_routine_name)
    call kim_convert_c_char_ptr_to_string(p, string)
  end subroutine kim_model_routine_name_to_string

  recursive subroutine kim_get_number_of_model_routine_names( &
    number_of_model_routine_names)
    implicit none
    interface
      recursive subroutine get_number_of_model_routine_names( &
        number_of_model_routine_names) &
        bind(c, name="KIM_MODEL_ROUTINE_NAME_GetNumberOfModelRoutineNames")
        use, intrinsic :: iso_c_binding
        integer(c_int), intent(out) :: number_of_model_routine_names
      end subroutine get_number_of_model_routine_names
    end interface
    integer(c_int), intent(out) :: number_of_model_routine_names

    call get_number_of_model_routine_names(number_of_model_routine_names)
  end subroutine kim_get_number_of_model_routine_names

  recursive subroutine kim_get_model_routine_name(index, &
                                                  model_routine_name, ierr)
    implicit none
    interface
      integer(c_int) recursive function get_model_routine_name( &
        index, model_routine_name) &
        bind(c, name="KIM_MODEL_ROUTINE_NAME_GetModelRoutineName")
        use, intrinsic :: iso_c_binding
        import kim_model_routine_name_type
        implicit none
        integer(c_int), intent(in), value :: index
        type(kim_model_routine_name_type), intent(out) :: &
          model_routine_name
      end function get_model_routine_name
    end interface
    integer(c_int), intent(in) :: index
    type(kim_model_routine_name_type), intent(out) :: model_routine_name
    integer(c_int), intent(out) :: ierr

    ierr = get_model_routine_name(index - 1, model_routine_name)
  end subroutine kim_get_model_routine_name
end module kim_model_routine_name_module